Pic ha scritto:
Non riesco a trovare sul forum un vecchio post che
traduceva per Metastock i codici di regolo
qualcuno può postarli?
si riesce ad adattare anche
regolo T?
grazie
Questo è il codice che mi sono tradotto, non quello precedentemente postato dal Team ( comunque funziona )
1- f Regolo B condition
{ f Regolo B }
IDCH:= ((0.5+(1.35/2))*Mov(H,10,S)) + ((0.5-( 1.35 /2))*Mov(L,10,S));
IDCL:= ((0.5-( 1.35 /2))*Mov(H,10,S)) + ((0.5+( 1.35 /2))*Mov(L,10,S)) ;
IDCM:= Mov(C,35,S) ;
IDC:=If(IDCM< IDCH AND IDCM> IDCL,0,1);
{f Regolo B MACD Buy 1 ; Sell -1 }
fMACD:=Mov(C,13,E)-Mov(C,23,E)-Mov(Mov(C,13,E)-Mov(C,23,E),9,E) ;
MACDSign:= If(fMACD>0,1,-1) ;
{f Regolo B condition Buy 1 ; Sell -1 }
KeltnerL:= ((0.5-( 0.95 /2))*Mov(H,10,S)) + ((0.5+( 0.95 /2))*Mov(L,10,S)) ;
KeltnerH:= ((0.5+(0.95/2))*Mov(H,10,S)) + ((0.5-( 0.95 /2))*Mov(L,10,S)) ;
Keltsign:= If(C>KeltnerH,1, If(C<KeltnerL,-1,PREV));
COND:= If(IDC = 0 ,PREV, If(MACDSign<>Keltsign,PREV ,MACDSign));
COND
-----------------------------------------------------------------------------------
1- f Regolo T condition
COND:=
If( Fml("f Regolo Piramiding")=1,1,
If( Fml("f Regolo Piramiding")=-1,-1,
If( Fml("f BOLF condition") =1,1,
If( Fml("f BOLF condition") =-1,-1,0))));
COND
---------------------------------------------------------------------------------
1- f Regolo Piramiding
{ Buy 1 ; Sell -1 }
{condizioni di Regolo BA }
RegBCOND:= FmlVar("f Regolo B Condition","COND") ; {stato di Regolo B ( 1 LONG -1 SHORT ) }
{condizioni di Piramiding }
SmooCanale:= If( IsUndefined(Ref(C,-1)), C , (((2/(20+1))*(C-PREV))+PREV)) ;
ELmL:= SmooCanale *(1-( 6/100)) ;
ELmH := SmooCanale *(1+( 6/100)) ;
EL := If( Mov(c,80,s) < ELmL,1 , If(Mov(c,80,s) > ELmH , -1 , 0 )) ;
SmooLent:= If( IsUndefined(Ref(C,-1)), C , (2/(50+1))*(c-PREV)+PREV) ;
Momento:= (SmooLent / Ref(SmooLent ,-9) -1)*100;
FL:= If(Momento > 2.5, 1 , If( Momento < -2.5, -1, 0 )) ;
COND:=
If(RegBCOND = EL AND RegBCOND = FL , RegBCOND,0 ) ;
COND
----------------------------------------------------------------------------------
4- f BOLF condition
{ Buy 1 ; Sell -1 }
BOL:= FmlVar("f BOL condition","COND") ;
RegB:= FmlVar("f Regolo B condition","COND") ;
COND:=If(BOL=RegB,RegB,0);
COND
---------------------------------------------------------------------------------
4- f BOL condition
{ Buy 1 ; Sell -1 }
KeltnerL:= ((0.5-( 1.55 /2))*Mov(H,10,S)) + ((0.5+( 1.55 /2))*Mov(L,10,S)) ;
KeltnerH:= ((0.5+(1.55/2))*Mov(H,10,S)) + ((0.5-( 1.55 /2))*Mov(L,10,S)) ;
{condizioni di BOL }
IDCH:= ((0.5+(4.9/2))*Mov(H,10,S)) + ((0.5-( 4.9 /2))*Mov(L,10,S)) ;
IDCL:= ((0.5-( 4.9 /2))*Mov(H,10,S)) + ((0.5+( 4.9 /2))*Mov(L,10,S)) ;
IDC:=If(Mov(C,35,S)> IDCH OR Mov(C,35,S)< IDCL,1,0);
COND:= If(IDC =0,
If(Ref(C,-1)<Ref(KeltnerL,-1) AND C>KeltnerL ,1 ,
If(Ref(C,-1)>Ref(KeltnerH,-1) AND C<KeltnerH ,-1 , PREV)),0);
COND
Ciao Taz